About

This SPARQL endpoint contains all UniProt data. It is free to access and supports the SPARQL 1.1 draft of January 2012.

There are 7,663,416,332 triples is this release. All triples are available in the default graph. There are 16 named graphs.

Examples

1. Select all taxa from the UniProt taxonomy:
   SELECT ?taxon
   FROM <http://purl.uniprot.org/taxonomy/>
   WHERE
   {
     ?taxon a up:Taxon
   }
2. Select all bacterial taxa, and their scientific name, from the UniProt taxonomy:
   SELECT ?taxon ?name
   WHERE
   {
     ?taxon a up:Taxon .
     ?taxon up:scientificName ?name .
     ?taxon rdfs:subClassOf <http://purl.uniprot.org/taxonomy/2>
   }
3. Select all E-Coli K12 (including strains) UniProt entries and their amino acid sequence:
   SELECT ?protein ?aa
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:organism ?organism .
     {   ?protein up:organism <http://purl.uniprot.org/taxonomy/83333> .
     } UNION {   ?protein up:organism ?organism .
     ?organism rdfs:subClassOf <http://purl.uniprot.org/taxonomy/83333> .
     }   ?protein up:sequence ?s .
     ?s rdf:value ?aa
   }
4. Select the UniProt entry with the mnemonic 'A4_HUMAN':
   SELECT ?protein
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:mnemonic 'A4_HUMAN'
   }
5. Select a mapping of UniProt to PDB entries using the UniProt cross-references to the PDB database:
   SELECT ?protein ?db
   WHERE
   {
     ?protein a up:Protein .
     ?protein rdfs:seeAlso ?db .
     ?db up:database <http://purl.uniprot.org/database/PDB>
   }
6. Select all cross-references to external databases of the category '3D structure databases' of UniProt entries that are classified with the keyword '3Fe-4S':
   SELECT DISTINCT ?link
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:classifiedWith <http://purl.uniprot.org/keywords/3> .
     ?protein rdfs:seeAlso ?link .
     ?link up:database ?db .
     ?db up:category '3D structure databases'
   }
   
7. Select all UniProt entries, and their recommended protein name, that have a preferred gene name that contains the text 'DNA':
   SELECT ?protein ?name
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:recommendedName ?recommended .
     ?recommended up:fullName ?name .
     ?protein up:encodedBy ?gene .
     ?gene skos:prefLabel ?text .
     FILTER CONTAINS(?text, 'DNA')
   }
8. Select the preferred gene name and disease annotation of all human UniProt entries that are known to be involved in a disease:
   SELECT ?name ?text
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:organism <http://purl.uniprot.org/taxonomy/9606> .
     ?protein up:encodedBy ?gene .
     ?gene skos:prefLabel ?name .
     ?protein up:annotation ?annotation .
     ?annotation a up:Disease_Annotation .
     ?annotation rdfs:comment ?text
   }
9. Select all human UniProt entries with a sequence variant that leads to a 'loss of function':
   SELECT ?protein ?text
   WHERE
   {
     ?protein a up:Protein .
     ?protein up:organism <http://purl.uniprot.org/taxonomy/9606> .
     ?protein up:annotation ?annotation .
     ?annotation a up:Natural_Variant_Annotation .
     ?annotation rdfs:comment ?text .
     FILTER (CONTAINS(?text, 'loss of function'))
   }
10. Select all human UniProt entries with a sequence variant that leads to a tyrosine to phenylalanine substitution:
    SELECT ?protein ?annotation ?begin ?text WHERE
    {
      ?protein a up:Protein .
      ?protein up:organism <http://purl.uniprot.org/taxonomy/9606> .
      ?protein up:annotation ?annotation .
      ?annotation a up:Natural_Variant_Annotation .
      ?annotation rdfs:comment ?text .
      ?annotation up:substitution ?substitution .
      ?annotation up:range/up:begin ?begin .
      ?protein up:sequence ?sequence .
      ?sequence rdf:value ?value .
      BIND (substr(?value, ?begin, 1) as ?orig) .
      FILTER(?original = 'Y' && ?substitution = 'F') .
    }
11. Select all UniProt entries with annotated transmembrane regions and the regions' begin and end coordinates on the canonical sequence:
    SELECT ?protein ?begin ?end
    WHERE
    {
      ?protein a up:Protein .
      ?protein up:annotation ?annotation .
      ?annotation a up:Transmembrane_Annotation .
      ?annotation up:range ?range .
      ?range up:begin ?begin .
      ?range up:end ?end
    }
12. Select all UniProt entries that were integrated on the 30th of November 2010:
    SELECT ?protein
    WHERE
    {
      ?protein a up:Protein .
      ?protein up:created '2010-11-30'^^xsd:date
    }
13. Was any UniProt entry integrated on the 9th of January 2013?
    ASK
    WHERE
    {
      ?protein a up:Protein .
      ?protein up:created '2013-01-09'^^xsd:date
    }
14. Construct new triples of the type 'HumanProtein' from all human UniProt entries:
    CONSTRUCT
    {
      ?protein a up:HumanProtein .
    }
    WHERE
    {
      ?protein a up:Protein .
      ?protein up:organism taxon:9606
    }
15. Select all triples that relate to the EMBL CDS entry AA089367.1:
    DESCRIBE <http://purl.uniprot.org/embl-cds/AAO89367.1>
16. Select all triples that relate to the taxon that describes Homo sapiens:
    DESCRIBE   taxon:9606
    FROM <http://purl.uniprot.org/taxonomy/>
    
17. Select the average number of cross-references to the PDB database of UniProt entries that have at least one cross-reference to the PDB database:
    SELECT (AVG(?linksToPdbPerEntry) AS ?avgLinksToPdbPerEntry)
    WHERE
    {
      SELECT ?protein (COUNT(DISTINCT ?db) AS ?linksToPdbPerEntry)
      WHERE
      {
        ?protein a up:Protein .
        ?protein rdfs:seeAlso ?db .
        ?db up:database <http://purl.uniprot.org/database/PDB>
      }
      GROUP BY ?protein ORDER BY DESC(?linksToPdbPerEntry)
    }
    
18. Select the number of UniProt entries for each of the EC (Enzyme Commission) second level categories:
    SELECT ?name (COUNT(?protein) as ?size)
    WHERE
    {
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/1.-.-.->
      }
      UNION
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/2.-.-.->
      }
      UNION
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/3.-.-.->
      }
      UNION
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/4.-.-.->
      }
      UNION
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/5.-.-.->
      }
      UNION
      {
        ?protein <http://purl.uniprot.org/core/enzyme> ?name.
        ?name rdfs:subClassOf <http://purl.uniprot.org/enzyme/6.-.-.->
      }
    }
    GROUP BY ?name order by ?name